home *** CD-ROM | disk | FTP | other *** search
/ Cream of the Crop 26 / Cream of the Crop 26.iso / os2 / octa209s.zip / octave-2.09 / libcruft / lapack / dgeqrf.f < prev    next >
Text File  |  1996-07-19  |  5KB  |  188 lines
  1.       SUBROUTINE DGEQRF( M, N, A, LDA, TAU, WORK, LWORK, INFO )
  2. *
  3. *  -- LAPACK routine (version 2.0) --
  4. *     Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
  5. *     Courant Institute, Argonne National Lab, and Rice University
  6. *     September 30, 1994
  7. *
  8. *     .. Scalar Arguments ..
  9.       INTEGER            INFO, LDA, LWORK, M, N
  10. *     ..
  11. *     .. Array Arguments ..
  12.       DOUBLE PRECISION   A( LDA, * ), TAU( * ), WORK( LWORK )
  13. *     ..
  14. *
  15. *  Purpose
  16. *  =======
  17. *
  18. *  DGEQRF computes a QR factorization of a real M-by-N matrix A:
  19. *  A = Q * R.
  20. *
  21. *  Arguments
  22. *  =========
  23. *
  24. *  M       (input) INTEGER
  25. *          The number of rows of the matrix A.  M >= 0.
  26. *
  27. *  N       (input) INTEGER
  28. *          The number of columns of the matrix A.  N >= 0.
  29. *
  30. *  A       (input/output) DOUBLE PRECISION array, dimension (LDA,N)
  31. *          On entry, the M-by-N matrix A.
  32. *          On exit, the elements on and above the diagonal of the array
  33. *          contain the min(M,N)-by-N upper trapezoidal matrix R (R is
  34. *          upper triangular if m >= n); the elements below the diagonal,
  35. *          with the array TAU, represent the orthogonal matrix Q as a
  36. *          product of min(m,n) elementary reflectors (see Further
  37. *          Details).
  38. *
  39. *  LDA     (input) INTEGER
  40. *          The leading dimension of the array A.  LDA >= max(1,M).
  41. *
  42. *  TAU     (output) DOUBLE PRECISION array, dimension (min(M,N))
  43. *          The scalar factors of the elementary reflectors (see Further
  44. *          Details).
  45. *
  46. *  WORK    (workspace/output) DOUBLE PRECISION array, dimension (LWORK)
  47. *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
  48. *
  49. *  LWORK   (input) INTEGER
  50. *          The dimension of the array WORK.  LWORK >= max(1,N).
  51. *          For optimum performance LWORK >= N*NB, where NB is
  52. *          the optimal blocksize.
  53. *
  54. *  INFO    (output) INTEGER
  55. *          = 0:  successful exit
  56. *          < 0:  if INFO = -i, the i-th argument had an illegal value
  57. *
  58. *  Further Details
  59. *  ===============
  60. *
  61. *  The matrix Q is represented as a product of elementary reflectors
  62. *
  63. *     Q = H(1) H(2) . . . H(k), where k = min(m,n).
  64. *
  65. *  Each H(i) has the form
  66. *
  67. *     H(i) = I - tau * v * v'
  68. *
  69. *  where tau is a real scalar, and v is a real vector with
  70. *  v(1:i-1) = 0 and v(i) = 1; v(i+1:m) is stored on exit in A(i+1:m,i),
  71. *  and tau in TAU(i).
  72. *
  73. *  =====================================================================
  74. *
  75. *     .. Local Scalars ..
  76.       INTEGER            I, IB, IINFO, IWS, K, LDWORK, NB, NBMIN, NX
  77. *     ..
  78. *     .. External Subroutines ..
  79.       EXTERNAL           DGEQR2, DLARFB, DLARFT, XERBLA
  80. *     ..
  81. *     .. Intrinsic Functions ..
  82.       INTRINSIC          MAX, MIN
  83. *     ..
  84. *     .. External Functions ..
  85.       INTEGER            ILAENV
  86.       EXTERNAL           ILAENV
  87. *     ..
  88. *     .. Executable Statements ..
  89. *
  90. *     Test the input arguments
  91. *
  92.       INFO = 0
  93.       IF( M.LT.0 ) THEN
  94.          INFO = -1
  95.       ELSE IF( N.LT.0 ) THEN
  96.          INFO = -2
  97.       ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
  98.          INFO = -4
  99.       ELSE IF( LWORK.LT.MAX( 1, N ) ) THEN
  100.          INFO = -7
  101.       END IF
  102.       IF( INFO.NE.0 ) THEN
  103.          CALL XERBLA( 'DGEQRF', -INFO )
  104.          RETURN
  105.       END IF
  106. *
  107. *     Quick return if possible
  108. *
  109.       K = MIN( M, N )
  110.       IF( K.EQ.0 ) THEN
  111.          WORK( 1 ) = 1
  112.          RETURN
  113.       END IF
  114. *
  115. *     Determine the block size.
  116. *
  117.       NB = ILAENV( 1, 'DGEQRF', ' ', M, N, -1, -1 )
  118.       NBMIN = 2
  119.       NX = 0
  120.       IWS = N
  121.       IF( NB.GT.1 .AND. NB.LT.K ) THEN
  122. *
  123. *        Determine when to cross over from blocked to unblocked code.
  124. *
  125.          NX = MAX( 0, ILAENV( 3, 'DGEQRF', ' ', M, N, -1, -1 ) )
  126.          IF( NX.LT.K ) THEN
  127. *
  128. *           Determine if workspace is large enough for blocked code.
  129. *
  130.             LDWORK = N
  131.             IWS = LDWORK*NB
  132.             IF( LWORK.LT.IWS ) THEN
  133. *
  134. *              Not enough workspace to use optimal NB:  reduce NB and
  135. *              determine the minimum value of NB.
  136. *
  137.                NB = LWORK / LDWORK
  138.                NBMIN = MAX( 2, ILAENV( 2, 'DGEQRF', ' ', M, N, -1,
  139.      $                 -1 ) )
  140.             END IF
  141.          END IF
  142.       END IF
  143. *
  144.       IF( NB.GE.NBMIN .AND. NB.LT.K .AND. NX.LT.K ) THEN
  145. *
  146. *        Use blocked code initially
  147. *
  148.          DO 10 I = 1, K - NX, NB
  149.             IB = MIN( K-I+1, NB )
  150. *
  151. *           Compute the QR factorization of the current block
  152. *           A(i:m,i:i+ib-1)
  153. *
  154.             CALL DGEQR2( M-I+1, IB, A( I, I ), LDA, TAU( I ), WORK,
  155.      $                   IINFO )
  156.             IF( I+IB.LE.N ) THEN
  157. *
  158. *              Form the triangular factor of the block reflector
  159. *              H = H(i) H(i+1) . . . H(i+ib-1)
  160. *
  161.                CALL DLARFT( 'Forward', 'Columnwise', M-I+1, IB,
  162.      $                      A( I, I ), LDA, TAU( I ), WORK, LDWORK )
  163. *
  164. *              Apply H' to A(i:m,i+ib:n) from the left
  165. *
  166.                CALL DLARFB( 'Left', 'Transpose', 'Forward',
  167.      $                      'Columnwise', M-I+1, N-I-IB+1, IB,
  168.      $                      A( I, I ), LDA, WORK, LDWORK, A( I, I+IB ),
  169.      $                      LDA, WORK( IB+1 ), LDWORK )
  170.             END IF
  171.    10    CONTINUE
  172.       ELSE
  173.          I = 1
  174.       END IF
  175. *
  176. *     Use unblocked code to factor the last or only block.
  177. *
  178.       IF( I.LE.K )
  179.      $   CALL DGEQR2( M-I+1, N-I+1, A( I, I ), LDA, TAU( I ), WORK,
  180.      $                IINFO )
  181. *
  182.       WORK( 1 ) = IWS
  183.       RETURN
  184. *
  185. *     End of DGEQRF
  186. *
  187.       END
  188.